Reorganize modules

modules/home/home.nix

@@ -0,0 +1,32 @@
+{ pkgs, lib, ... }:
+
+{
+  # Home Manager state version
+  home.stateVersion = "25.11";
+
+  home.username = "avravels";
+  home.homeDirectory = "/home/avravels";
+
+  imports = [
+    ./other/fonts.nix
+    #    ./programs/bitwarden.nix
+    ./programs/kitty.nix
+    ./programs/zsh.nix
+    ./programs/direnv.nix
+    ./programs/firefox.nix
+    ./programs/tmux.nix
+    ./programs/git.nix
+    ./programs/libreoffice.nix
+    ./programs/nvim.nix
+    ./programs/ripgrep.nix
+    ./programs/vscode.nix
+    ./wm/rofi.nix
+    ./wm/cursor.nix
+    ./wm/dconf.nix
+    ./wm/gtk.nix
+    ./wm/waybar.nix
+    ./wm/hyprland.nix
+    ./wm/hyprpaper.nix
+  ];
+
+}

modules/home/other/fonts.nix

@@ -0,0 +1,13 @@
+{ pkgs, ... }:
+
+{
+  fonts.fontconfig.enable = true;
+
+  home.packages = with pkgs; [
+    nerd-fonts.fira-code
+    nerd-fonts.droid-sans-mono
+    nerd-fonts.noto
+    nerd-fonts.hack
+    nerd-fonts.ubuntu
+  ];
+}

modules/home/programs/bitwarden.nix

@@ -0,0 +1,7 @@
+{ pkgs, ... }:
+
+{
+  home.packages = [
+    pkgs.bitwarden-desktop
+  ];
+}

modules/home/programs/direnv.nix

@@ -0,0 +1,13 @@
+{ pkgs, config, ... }:
+
+{
+  programs.direnv = {
+    enable = true;
+    enableZshIntegration = true;
+    nix-direnv.enable = true;
+  };
+
+  home.file.".config/direnv/direnvrc" = {
+    source = ./direnv/direnvrc;
+  };
+}

modules/home/programs/direnv/direnvrc

@@ -0,0 +1,15 @@
+# Place in ~/.config/direnv/direnvrc
+
+# Two things to know:
+# * `direnv_layour_dir` is called once for every {.direnvrc,.envrc} sourced
+# * The indicator for a different direnv file being sourced is a different $PWD value
+# This means we can hash $PWD to get a fully unique cache path for any given environment
+
+: ${XDG_CACHE_HOME:=$HOME/.cache}
+declare -A direnv_layout_dirs
+direnv_layout_dir() {
+	echo "${direnv_layout_dirs[$PWD]:=$(
+		echo -n "$XDG_CACHE_HOME"/direnv/layouts/
+		echo -n "$PWD" | sha1sum | cut -d ' ' -f 1
+	)}"
+}

modules/home/programs/fastfetch/config.jsonc

@@ -0,0 +1,12 @@
+{
+  "$schema": "https://github.com/fastfetch-cli/fastfetch/raw/master/doc/json_schema.json",
+  "modules": [
+    "os",
+    "uptime",
+    "cpu",
+    "gpu",
+    "memory",
+    "swap",
+    "disk",
+  ]
+}

modules/home/programs/firefox.nix

@@ -0,0 +1,39 @@
+{ pkgs, config, ... }:
+
+{
+  programs.firefox = {
+    enable = true;
+    configPath = "${config.xdg.configHome}/mozilla/firefox";
+    profiles.default = {
+      settings = {
+        "extensions.activeThemeID" = "firefox-compact-dark@mozilla.org";
+      };
+    };
+
+    policies = {
+      # From https://discourse.nixos.org/t/declare-firefox-extensions-and-settings/36265/17
+      ExtensionSettings =
+        with builtins;
+        let
+          extension = shortId: uuid: {
+            name = uuid;
+            value = {
+              install_url = "https://addons.mozilla.org/en-US/firefox/downloads/latest/${shortId}/latest.xpi";
+              installation_mode = "normal_installed";
+            };
+          };
+        in
+        listToAttrs [
+          (extension "bitwarden-password-manager" "{446900e4-71c2-419f-a6a7-df9c091e268b}")
+          (extension "ublock-origin" "uBlock0@raymondhill.net")
+          (extension "privacy-badger17" "jid1-MnnxcxisBPnSXQ@jetpack")
+          (extension "i-dont-care-about-cookies" "jid1-KKzOGWgsW3Ao4Q@jetpack")
+        ];
+      # To add additional extensions, find it on addons.mozilla.org, find
+      # the short ID in the url (like https://addons.mozilla.org/en-US/firefox/addon/!SHORT_ID!/)
+      # Then, download the XPI by filling it in to the install_url template, unzip it,
+      # run `jq .browser_specific_settings.gecko.id manifest.json` or
+      # `jq .applications.gecko.id manifest.json` to get the UUID
+    };
+  };
+}

modules/home/programs/git.nix

@@ -0,0 +1,32 @@
+{ lib
+, pkgsUnstable
+, config
+, ...
+}:
+
+{
+  options.home.git = {
+    userName = lib.mkOption {
+      type = lib.types.str;
+      default = "Armel van Ravels";
+      description = "Default git user.name for this user";
+    };
+
+    userEmail = lib.mkOption {
+      type = lib.types.str;
+      default = "armel@armel.nl";
+      description = "Default git user.email for this user";
+    };
+  };
+
+  config = {
+    programs.git = {
+      enable = true;
+      package = pkgsUnstable.git;
+      settings.user = {
+        name = config.home.git.userName;
+        email = config.home.git.userEmail;
+      };
+    };
+  };
+}

modules/home/programs/kitty.nix

@@ -0,0 +1,8 @@
+{ pkgs, ... }:
+
+{
+  programs.kitty = {
+    enable = true;
+    settings.confirm_quit = false;
+  };
+}

modules/home/programs/libreoffice.nix

@@ -0,0 +1,11 @@
+{ pkgs, ... }:
+
+{
+  home.packages = with pkgs; [
+    libreoffice
+
+    hunspell
+    hunspellDicts.en_US
+    hunspellDicts.nl_NL
+  ];
+}

modules/home/programs/nvim.nix

@@ -0,0 +1,161 @@
+{ pkgs, ... }:
+
+{
+  programs.neovim = {
+    enable = true;
+    withRuby = false;
+    withPython3 = false;
+    defaultEditor = true;
+    extraLuaPackages = ps: [ ps.magick ];
+    extraPackages = [
+      pkgs.ueberzugpp
+      pkgs.imagemagick
+    ];
+
+    plugins = with pkgs.vimPlugins; [
+      neo-tree-nvim
+      catppuccin-nvim
+      tokyonight-nvim
+      nvim-lspconfig
+      nvim-cmp
+      cmp-nvim-lsp
+      cmp-buffer
+      cmp-path
+      plenary-nvim
+      telescope-nvim
+      (nvim-treesitter.withAllGrammars)
+      vim-nix
+      lualine-nvim
+      image-nvim
+    ];
+
+    initLua = ''
+        vim.cmd("colorscheme catppuccin-mocha")
+        -- Basic settings
+        vim.o.number = true
+        vim.o.relativenumber = true
+
+        -- =========================
+        -- LSP (Neovim 0.11+ way)
+        -- =========================
+
+        -- Add cmp capabilities
+        local capabilities = require("cmp_nvim_lsp").default_capabilities()
+
+        vim.lsp.config("nil_ls", {
+          capabilities = capabilities,
+        })
+
+        -- PHP LSP
+        vim.lsp.config("intelephense", {
+          capabilities = capabilities,
+        })
+
+        vim.lsp.enable("intelephense")
+
+
+        vim.lsp.enable("nil_ls")
+
+        -- =========================
+        -- nvim-cmp
+        -- =========================
+
+        local cmp = require("cmp")
+
+        cmp.setup({
+          mapping = cmp.mapping.preset.insert({
+            ["<C-Space>"] = cmp.mapping.complete(),
+            ["<CR>"] = cmp.mapping.confirm({ select = true }),
+          }),
+          sources = {
+            { name = "nvim_lsp" },
+            { name = "buffer" },
+            { name = "path" },
+          }
+        })
+
+        -- =========================
+        -- Telescope
+        -- =========================
+
+        local builtin = require("telescope.builtin")
+        vim.keymap.set("n", "<leader>ff", builtin.find_files, {})
+        vim.keymap.set("n", "<leader>fg", builtin.live_grep, {})
+
+        -- =========================
+        -- Lualine (status line with Git branch)
+        -- =========================
+        require('lualine').setup {
+          options = {
+            theme = 'catppuccin',  -- match your colorscheme
+            section_separators = {'', ''},
+            component_separators = {'', ''},
+          },
+          sections = {
+            lualine_a = {'mode'},
+            lualine_b = {'branch'},  -- shows Git branch here
+            lualine_c = {'filename'},
+            lualine_x = {'encoding', 'fileformat', 'filetype'},
+            lualine_y = {'progress'},
+            lualine_z = {'location'}
+          }
+        }
+
+        -- =========================
+        -- image-nvim
+        -- ========================= 
+        require("image").setup({
+          backend = "ueberzug", -- or "ueberzug" or "sixel"
+          processor = "magick_cli", -- or "magick_rock"
+          integrations = {
+          markdown = {
+            enabled = true,
+            clear_in_insert_mode = false,
+            download_remote_images = true,
+            only_render_image_at_cursor = false,
+            only_render_image_at_cursor_mode = "popup", -- or "inline"
+            floating_windows = false, -- if true, images will be rendered in floating markdown windows
+            filetypes = { "markdown", "vimwiki" }, -- markdown extensions (ie. quarto) can go here
+          },
+          asciidoc = {
+            enabled = true,
+            clear_in_insert_mode = false,
+            download_remote_images = true,
+            only_render_image_at_cursor = false,
+            only_render_image_at_cursor_mode = "popup",
+            floating_windows = false,
+            filetypes = { "asciidoc", "adoc" },
+          },
+          neorg = {
+            enabled = true,
+            filetypes = { "norg" },
+          },
+          rst = {
+            enabled = true,
+          },
+          typst = {
+            enabled = true,
+            filetypes = { "typst" },
+          },
+          html = {
+            enabled = false,
+          },
+          css = {
+            enabled = false,
+          },
+        },
+        max_width = nil,
+        max_height = nil,
+        max_width_window_percentage = nil,
+        max_height_window_percentage = 50,
+        scale_factor = 1.0,
+        window_overlap_clear_enabled = false, -- toggles images when windows are overlapped
+        window_overlap_clear_ft_ignore = { "cmp_menu", "cmp_docs", "snacks_notif", "scrollview", "scrollview_sign" },
+        editor_only_render_when_focused = false, -- auto show/hide images when the editor gains/looses focus
+        tmux_show_only_in_active_window = false, -- auto show/hide images in the correct Tmux window (needs visual-activity off)
+        hijack_file_patterns = { "*.png", "*.jpg", "*.jpeg", "*.gif", "*.webp", "*.avif" }, -- render image files as images when opened
+      })
+
+    '';
+  };
+}

modules/home/programs/ripgrep.nix

@@ -0,0 +1,7 @@
+{ pkgs, ... }:
+
+{
+  home.packages = with pkgs; [
+    ripgrep
+  ];
+}

modules/home/programs/tmux.nix

@@ -0,0 +1,8 @@
+{ pkgs, ... }:
+
+{
+  programs.tmux = {
+    enable = true;
+    mouse = true;
+  };
+}

modules/home/programs/vscode.nix

@@ -0,0 +1,47 @@
+{ pkgs, pkgsUnstable, ... }:
+
+let
+  extensions = with pkgs.vscode-extensions; [
+    ms-dotnettools.csharp
+    ms-dotnettools.csdevkit
+    ms-dotnettools.vscode-dotnet-runtime
+    mkhl.direnv
+    catppuccin.catppuccin-vsc
+    bmewburn.vscode-intelephense-client
+    continue.continue
+    vue.volar
+    ms-vscode-remote.remote-containers
+  ];
+
+  userSettings = {
+    "editor.lineNumbers" = "relative";
+    "workbench.colorTheme" = "Catppuccin Mocha";
+    "workbench.editor.enablePreview" = false;
+    "direnv.restart.automatic" = true;
+
+    "terminal.integrated.defaultProfile.linux" = "zsh";
+    "terminal.integrated.profiles.linux".zsh = {
+      path = "${pkgs.zsh}/bin/zsh";
+    };
+  };
+
+  editors = {
+    vscode = pkgsUnstable.vscode.fhs;
+    cursor = pkgsUnstable.code-cursor-fhs;
+    vscodium = pkgsUnstable.vscodium-fhs;
+  };
+
+  mkEditor = package: {
+    enable = true;
+    inherit package;
+
+    profiles.default = {
+      inherit extensions;
+      inherit userSettings;
+    };
+  };
+
+in
+{
+  programs = builtins.mapAttrs (_: mkEditor) editors;
+}

modules/home/programs/zsh.nix

@@ -0,0 +1,22 @@
+{ pkgs, ... }:
+
+{
+  home.file.".zsh/fastfetch.jsonc".source = ./fastfetch/config.jsonc;
+  home.file.".zsh/functions/dex.zsh".source = ./zsh/functions/dex.zsh;
+
+  programs.zsh = {
+    enable = true;
+
+    oh-my-zsh = {
+      enable = true;
+      theme = "agnoster";
+    };
+
+    initContent = ''
+      # Use kitty's ssh helper if running inside kitty
+      [ "$TERM" = "xterm-kitty" ] && alias ssh="kitty +kitten ssh"
+
+      source ~/.zsh/functions/dex.zsh
+    '';
+  };
+}

modules/home/programs/zsh/functions/dex.zsh

@@ -0,0 +1,59 @@
+dex() {
+  clear
+  local container
+
+  container=$(
+    docker ps --format '{{.Names}}\t{{.Image}}\t{{.Status}}' |
+      sort |
+      fzf \
+        --delimiter=$'\t' \
+        --with-nth=1,2,3 \
+        --header=$'Ctrl-I: Inspect | Ctrl-L: Logs | Ctrl-R: Refresh | ?: Toggle Preview\n\nNAME\tIMAGE\tSTATUS' \
+        --tabstop=4 \
+        --height=100% \
+        --layout=reverse \
+        --border=rounded \
+        --info=inline-right \
+        --prompt='🐳 Container > ' \
+        --pointer='▶' \
+        --marker='✓' \
+        --preview 'docker logs -f --tail=50 {1} 2>&1' \
+        --preview-label=' Logs ' \
+        --preview-window='right,65%,follow,border-left,wrap' \
+        --bind 'ctrl-r:reload(docker ps --format "{{.Names}}\t{{.Image}}\t{{.Status}}" | sort)' \
+        --bind 'ctrl-u:preview-half-page-up' \
+        --bind 'ctrl-d:preview-half-page-down' \
+        --bind '?:toggle-preview' \
+        --bind 'ctrl-l:change-preview(docker logs -f --tail=50 {1} 2>&1)+change-preview-label(Logs)' \
+        --bind 'ctrl-i:change-preview(
+          docker inspect --format "
+Name:      {{.Name}}
+Image:     {{.Config.Image}}
+Status:    {{.State.Status}}
+Running:   {{.State.Running}}
+Started:   {{.State.StartedAt}}
+Finished:  {{.State.FinishedAt}}
+PID:       {{.State.Pid}}
+Exit Code: {{.State.ExitCode}}
+
+Networks:
+{{range .NetworkSettings.Networks}}  • {{.IPAddress}}
+{{end}}
+
+Mounts:
+{{range .Mounts}}  • {{.Source}} -> {{.Destination}}
+{{end}}
+" {1}
+        )+change-preview-label(Inspect)' |
+      cut -f1
+  ) || return
+
+  docker exec -it "$container" sh -c '
+    for shell in bash ash zsh sh; do
+      command -v "$shell" >/dev/null 2>&1 && exec "$shell"
+    done
+
+    echo "No suitable shell found." >&2
+    exit 1
+  '
+}

modules/home/wm/cursor.nix

@@ -0,0 +1,13 @@
+{ pkgs, ... }:
+
+{
+  home.pointerCursor = {
+    #    name = "Bibata-Modern-Ice";   # change to your cursor theme
+    #    package = pkgs.bibata-cursors;
+    name = "Adwaita";
+    package = pkgs.adwaita-icon-theme;
+    size = 24;
+    gtk.enable = true;
+    x11.enable = true;
+  };
+}

modules/home/wm/dconf.nix

@@ -0,0 +1,16 @@
+{ pkgs, ... }:
+
+{
+  home.packages = with pkgs; [
+    dconf
+  ];
+
+  dconf = {
+    enable = true;
+    settings = {
+      "org/gnome/desktop/interface" = {
+        color-scheme = "prefer-dark";
+      };
+    };
+  };
+}

modules/home/wm/gtk.nix

@@ -0,0 +1,27 @@
+{ pkgs, ... }:
+
+{
+  gtk = {
+    enable = true;
+    theme = {
+      name = "Orchis-dark";
+      package = pkgs.orchis-theme;
+    };
+    iconTheme = {
+      name = "Adwaita";
+      package = pkgs.adwaita-icon-theme;
+    };
+    cursorTheme = {
+      name = "Adwaita";
+      package = pkgs.adwaita-icon-theme;
+    };
+    gtk4.theme = null;
+  };
+
+  home.sessionVariables = {
+    GTK_THEME = "Adwaita:dark"; # GTK apps dark theme
+    MOZ_GTK_THEME = "Adwaita:dark"; # Firefox respects this
+    GDK_DARK_THEME = "1"; # GTK4 apps dark mode
+    CHROME_FORCE_DARK_MODE = "1"; # Chromium / Chrome dark mode
+  };
+}

modules/home/wm/hyprland.nix

@@ -0,0 +1,216 @@
+{ lib
+, pkgs
+, config
+, ...
+}:
+
+let
+  cfg = config.home.hyprland;
+  toggleRecorder = import ./scripts/toggle-recorder.nix { inherit pkgs; };
+in
+{
+  options.home.hyprland.monitors = lib.mkOption {
+    type = lib.types.listOf (lib.types.submodule {
+      options = {
+        output = lib.mkOption { type = lib.types.str; };
+        mode = lib.mkOption {
+          type = lib.types.str;
+          default = "preferred";
+        };
+        position = lib.mkOption {
+          type = lib.types.str;
+          default = "auto";
+        };
+        scale = lib.mkOption {
+          type = lib.types.number;
+          default = 1;
+        };
+      };
+    });
+    default = [ ];
+  };
+
+  config = {
+    home.packages = with pkgs; [
+      bzmenu
+      hyprshot
+      hyprlock
+      playerctl
+      speedcrunch
+      toggleRecorder
+    ];
+    wayland.windowManager.hyprland = {
+      enable = true;
+      configType = "lua";
+      settings =
+        let
+          mkLuaInline = lib.generators.mkLuaInline;
+          toLua = lib.generators.toLua;
+          mkArgs = args: { _args = args; };
+          defaultMonitor = {
+            output = "";
+            mode = "preferred";
+            position = "auto";
+            scale = 1;
+          };
+          bind =
+            keys: dispatcher: options:
+            mkArgs [
+              keys
+              dispatcher
+              options
+            ];
+          dsp = {
+            exec_cmd = app: mkLuaInline ''hl.dsp.exec_cmd("${app}")'';
+            focus = arg: mkLuaInline "hl.dsp.focus(${toLua { } arg})";
+            window = {
+              move = arg: mkLuaInline "hl.dsp.window.move(${toLua { } arg})";
+              drag = mkLuaInline "hl.dsp.window.drag()";
+              resize = mkLuaInline "hl.dsp.window.resize()";
+              close = mkLuaInline "hl.dsp.window.close()";
+              kill = mkLuaInline "hl.dsp.window.kill()";
+              fullscreen = mkLuaInline "hl.dsp.window.fullscreen()";
+            };
+            exit = mkLuaInline "hl.dsp.exit()";
+            workspace = {
+              move = arg: mkLuaInline "hl.dsp.workspace.move(${toLua { } arg})";
+            };
+          };
+          mod = "SUPER";
+          workspaces = lib.stringToCharacters "abcdefgimnopqrstuvwxyz";
+        in
+        {
+          config = {
+            general = {
+              resize_on_border = true;
+              allow_tearing = true;
+            };
+
+            animations.enabled = true;
+
+            decoration = {
+              inactive_opacity = 0.7;
+              active_opacity = 0.9;
+              rounding = 5;
+              rounding_power = 2.5;
+              blur = {
+                enabled = true;
+                brightness = 1.0;
+                contrast = 1.0;
+                noise = 0.01;
+
+                vibrancy = 0.2;
+                vibrancy_darkness = 0.5;
+
+                passes = 4;
+                size = 7;
+
+                popups = true;
+                popups_ignorealpha = 0.2;
+              };
+              shadow = {
+                enabled = true;
+                color = "rgba(00000055)";
+                offset = "0 15";
+                range = 100;
+                render_power = 2;
+                scale = 0.97;
+              };
+            };
+
+            misc = {
+              focus_on_activate = true;
+            };
+          };
+
+          bind = lib.flatten [
+            (bind "${mod} + W" (dsp.exec_cmd "pkill -SIGUSR1 -f '^waybar$'") { })
+            (bind "${mod} + Q" (dsp.window.close) { })
+            (bind "${mod} + L" (dsp.exec_cmd "hyprlock") { })
+            (bind "${mod} + D" (dsp.exec_cmd "rofi -show drun") { })
+            (bind "${mod} + B" (dsp.exec_cmd "bzmenu --launcher rofi") { })
+            (bind "${mod} + F" (dsp.window.fullscreen) { })
+            (bind "${mod} + Z" (dsp.exec_cmd "hyprshot -m region") { })
+            (bind "${mod} + SHIFT + Z" (dsp.exec_cmd "toggle-recorder") { })
+            (bind "${mod} + M" (dsp.exit) { })
+            (bind "${mod} + SPACE" (dsp.exec_cmd "firefox") { })
+            (bind "${mod} + RETURN" (dsp.exec_cmd "kitty") { })
+
+            (bind "${mod} + SHIFT + LEFT" (dsp.window.move { direction = "l"; }) { })
+            (bind "${mod} + SHIFT + DOWN" (dsp.window.move { direction = "d"; }) { })
+            (bind "${mod} + SHIFT + UP" (dsp.window.move { direction = "u"; }) { })
+            (bind "${mod} + SHIFT + RIGHT" (dsp.window.move { direction = "r"; }) { })
+
+            (bind "${mod} + LEFT" (dsp.focus { direction = "l"; }) { })
+            (bind "${mod} + DOWN" (dsp.focus { direction = "d"; }) { })
+            (bind "${mod} + UP" (dsp.focus { direction = "u"; }) { })
+            (bind "${mod} + RIGHT" (dsp.focus { direction = "r"; }) { })
+
+            (bind "${mod} + 1" (dsp.focus { workspace = 1; }) { })
+            (bind "${mod} + 2" (dsp.focus { workspace = 2; }) { })
+            (bind "${mod} + 3" (dsp.focus { workspace = 3; }) { })
+            (bind "${mod} + 4" (dsp.focus { workspace = 4; }) { })
+            (bind "${mod} + 5" (dsp.focus { workspace = 5; }) { })
+            (bind "${mod} + 6" (dsp.focus { workspace = 6; }) { })
+            (bind "${mod} + 7" (dsp.focus { workspace = 7; }) { })
+            (bind "${mod} + 8" (dsp.focus { workspace = 8; }) { })
+            (bind "${mod} + 9" (dsp.focus { workspace = 9; }) { })
+
+            (bind "${mod} + SHIFT + 1" (dsp.window.move { workspace = 1; }) { })
+            (bind "${mod} + SHIFT + 2" (dsp.window.move { workspace = 2; }) { })
+            (bind "${mod} + SHIFT + 3" (dsp.window.move { workspace = 3; }) { })
+            (bind "${mod} + SHIFT + 4" (dsp.window.move { workspace = 4; }) { })
+            (bind "${mod} + SHIFT + 5" (dsp.window.move { workspace = 5; }) { })
+            (bind "${mod} + SHIFT + 6" (dsp.window.move { workspace = 6; }) { })
+            (bind "${mod} + SHIFT + 7" (dsp.window.move { workspace = 7; }) { })
+            (bind "${mod} + SHIFT + 8" (dsp.window.move { workspace = 8; }) { })
+            (bind "${mod} + SHIFT + 9" (dsp.window.move { workspace = 9; }) { })
+
+            (bind "XF86AudioLowerVolume" (dsp.exec_cmd "wpctl set-volume @DEFAULT_AUDIO_SINK@ 5%-") {
+              repeating = true;
+              locked = true;
+            })
+            (bind "XF86AudioRaiseVolume" (dsp.exec_cmd "wpctl set-volume @DEFAULT_AUDIO_SINK@ 5%+") {
+              repeating = true;
+              locked = true;
+            })
+            (bind "XF86AudioPlay" (dsp.exec_cmd "playerctl play-pause") { locked = true; })
+            (bind "XF86AudioPrev" (dsp.exec_cmd "playerctl previous") { locked = true; })
+            (bind "XF86AudioNext" (dsp.exec_cmd "playerctl next") { locked = true; })
+
+            (bind "${mod} + mouse:272" dsp.window.drag { mouse = true; })
+            (bind "${mod} + mouse:273" dsp.window.resize { mouse = true; })
+          ];
+          on = [
+            (mkArgs [
+              "hyprland.start"
+              (mkLuaInline ''
+                function()
+                  hl.exec_cmd("waybar")
+
+                  hl.monitor(${toLua {} defaultMonitor})
+
+                  ${lib.concatMapStringsSep "\n"
+                    (m: "hl.monitor(${toLua {} m})")
+                    cfg.monitors}
+                end
+              '')
+            ])
+
+            (mkArgs [
+              "config.reloaded"
+              (mkLuaInline ''
+                function()
+                  hl.monitor(${toLua {} defaultMonitor})
+
+                  ${lib.concatMapStringsSep "\n"
+                    (m: "hl.monitor(${toLua {} m})")
+                    cfg.monitors}
+                end
+              '')
+            ])
+          ];
+        };
+    };
+  };
+}

modules/home/wm/hyprpaper.nix

@@ -0,0 +1,30 @@
+{ config, pkgs, ... }:
+
+let
+  wallpaper = builtins.toString ../backgrounds/monkey.jpg;
+  wallpaper2 = builtins.toString ../backgrounds/bird.jpg;
+  wallpaper3 = builtins.toString ../backgrounds/nix.png;
+  wallpaper4 = builtins.toString ../backgrounds/catppucin.png;
+in
+{
+  services.hyprpaper = {
+    enable = true;
+
+    settings = {
+      splash = false;
+      preload = [
+        wallpaper
+        wallpaper2
+        wallpaper3
+        wallpaper4
+      ];
+
+      wallpaper = [
+        {
+          monitor = "";
+          path = wallpaper4;
+        }
+      ];
+    };
+  };
+}

modules/home/wm/rofi.nix

@@ -0,0 +1,13 @@
+{ pkgs, ... }:
+
+{
+  home.packages = [
+    pkgs.rofi-file-browser
+  ];
+
+  programs.rofi = {
+    enable = true;
+    theme = "material";
+    terminal = "${pkgs.kitty}/bin/kitty";
+  };
+}

modules/home/wm/scripts/toggle-recorder.nix

@@ -0,0 +1,22 @@
+{ pkgs }:
+
+pkgs.writeShellApplication {
+  name = "toggle-recorder";
+
+  runtimeInputs = with pkgs; [
+    wf-recorder
+    slurp
+    procps
+    coreutils
+  ];
+
+  text = ''
+    if pgrep -x wf-recorder >/dev/null; then
+      pkill -INT wf-recorder
+    else
+      wf-recorder \
+        -g "$(slurp)" \
+        -f "$HOME/Videos/recording-$(date +%F-%H%M%S).mp4"
+    fi
+  '';
+}

modules/home/wm/waybar.nix

@@ -0,0 +1,85 @@
+{ pkgs, ... }:
+
+{
+  programs.waybar = {
+    enable = true;
+
+    style = builtins.readFile ./waybar/waybar-style.css;
+
+    settings.mainBar = {
+      layer = "top";
+      position = "top";
+      height = 30;
+
+      modules-left = [
+        "hyprland/workspaces"
+        "mpris"
+      ];
+
+      modules-center = [
+        "wlr/taskbar"
+      ];
+
+      modules-right = [
+        "custom/recording"
+        "pulseaudio"
+        "cpu"
+        "tray"
+        "clock"
+      ];
+
+      "custom/recording" = {
+        exec = ''
+          if pgrep -x wf-recorder >/dev/null; then
+            echo "🔴 REC"
+          fi
+        '';
+        interval = 1;
+        tooltip = false;
+      };
+
+      pulseaudio = {
+        format = "{icon} {volume}%";
+        format-muted = "󰝟 muted";
+        tooltip = false;
+
+        scroll-step = 5;
+
+        format-icons = {
+          default = [
+            "󰕿"
+            "󰖀"
+            "󰕾"
+          ];
+        };
+
+        on-click = "wpctl set-mute @DEFAULT_AUDIO_SINK@ toggle";
+      };
+
+      mpris = {
+        player = "spotify";
+        format = "{player_icon} {artist} - {title}";
+        format-paused = "{player_icon} ⏸ {title}";
+        tooltip = true;
+        ignored-players = [
+          "firefox"
+          "vlc"
+        ];
+      };
+
+      cpu = {
+        format = "  {usage}%";
+        tooltip = false;
+      };
+
+      clock = {
+        tooltip = false;
+      };
+
+      "wlr/taskbar" = {
+        format = "{icon} {name}";
+        on-click = "activate";
+      };
+    };
+  };
+}

modules/home/wm/waybar/waybar-style.css

@@ -0,0 +1,82 @@
+/* ---------------------------
+   Default Waybar Styling
+--------------------------- */
+
+* {
+  color: #ffffff;
+}
+
+
+menu {
+  background-color: #222222;
+  border-radius: 8px;
+  border: 1px solid #313244;
+}
+
+menu menuitem {
+  padding: 6px 12px;
+  color: #cdd6f4;
+}
+
+menu menuitem:hover {
+  background-color: #45475a;
+}
+
+/* General bar */
+#waybar {
+    background-color: #222222;  /* Default dark gray bar */
+    color: #ffffff;             /* Default text color */
+}
+
+/* Modules */
+.module {
+    margin: 0 4px;
+}
+
+/* Hover effect (minimal) */
+.module:hover {
+    opacity: 0.8;
+}
+
+/* Separators */
+.separator {
+    margin: 0 2px;
+}
+
+#taskbar button {
+  background: transparent;
+  border: none;
+  box-shadow: none;
+}
+
+#taskbar button:hover {
+  background-color: rgba(180, 190, 254, 0.15);
+  border-radius: 6px;
+}
+
+#taskbar button.active {
+  background-color: rgba(180, 190, 254, 0.3);
+}
+
+/* Workspace buttons */
+#workspaces button {
+  background: transparent;
+  border: none;
+  box-shadow: none;
+}
+
+/* Hover */
+#workspaces button:hover {
+  background-color: rgba(180, 190, 254, 0.15);
+  border-radius: 6px;
+}
+
+/* Active workspace */
+#workspaces button.active {
+  background-color: rgba(180, 190, 254, 0.35);
+}
+
+/* Icons */
+i {
+    margin-right: 2px;
+}