Add gimp to gandalf system

Reviewed-on: #14

README.md

@@ -0,0 +1,25 @@
+# NixOS Configurations (Flakes)
+
+This repository manages multiple **NixOS system configurations** using **flakes** and **Home Manager**. 
+Each system has its own dedicated configuration module.
+
+## Supported Systems
+
+| System Name | Description |
+|-------------|-------------|
+| **gandalf** | Personal system configuration for `gandalf`. |
+| **frodo**   | Personal system configuration for `frodo`. |
+| **legolas** | Personal system configuration for `legolas`. |
+| **work**    | Work-oriented system configuration for `work`. |
+
+
+## Rebuild a System
+
+To rebuild and switch to a specific system:
+
+```bash
+# Replace <system> with gandalf, frodo, legolas, or work
+sudo nixos-rebuild switch --flake .#<system>
+```
+
+

flake.lock

@@ -7,11 +7,11 @@
         ]
       },
       "locked": {
-        "lastModified": 1772633058,
-        "narHash": "sha256-SO7JapRy2HPhgmqiLbfnW1kMx5rakPMKZ9z3wtRLQjI=",
+        "lastModified": 1774875830,
+        "narHash": "sha256-WPYlTmZvVa9dWlAziFkVjBdv1Z6giNIq40O1DxsBmiI=",
         "owner": "nix-community",
         "repo": "home-manager",
-        "rev": "080657a04188aca25f8a6c70a0fb2ea7e37f1865",
+        "rev": "7afd8cebb99e25a64a745765920e663478eb8830",
         "type": "github"
       },
       "original": {
@@ -23,11 +23,11 @@
     },
     "nixpkgs": {
       "locked": {
-        "lastModified": 1772598333,
-        "narHash": "sha256-YaHht/C35INEX3DeJQNWjNaTcPjYmBwwjFJ2jdtr+5U=",
+        "lastModified": 1774799055,
+        "narHash": "sha256-Tsq9BCz0q47ej1uFF39m4tuhcwru/ls6vCCJzutEpaw=",
         "owner": "nixos",
         "repo": "nixpkgs",
-        "rev": "fabb8c9deee281e50b1065002c9828f2cf7b2239",
+        "rev": "107cba9eb4a8d8c9f8e9e61266d78d340867913a",
         "type": "github"
       },
       "original": {

outputs.nix

@@ -23,5 +23,12 @@
         ./systems/legolas
       ];
     };
+    "work" = nixpkgs.lib.nixosSystem {
+      system = "x86_64-linux";
+      modules = [
+        home-manager.nixosModules.home-manager
+        ./systems/work
+      ];
+    };
   };
 }

systems/gandalf/default.nix

@@ -4,6 +4,7 @@
   imports =
     [
       ./hardware-configuration.nix
+      ../modules/home-manager.nix
       ../modules/common.nix
       ../modules/users.nix
       ../modules/locales.nix
@@ -17,6 +18,10 @@
       ../modules/matrix.nix
       ../modules/kdenlive.nix
       ../modules/audacity.nix
+      ../modules/ollama.nix
+      ../modules/wireguard.nix
+      ../modules/qbittorrent.nix
+      ../modules/gimp.nix
     ];
 
   boot.loader.systemd-boot.enable = true;
@@ -26,10 +31,18 @@
   networking.networkmanager.enable = true;
   networking.nameservers = [ "192.168.68.56" "1.1.1.1" "8.8.8.8" ];
 
+  home-manager.users.avravels.home.hyprland.execOnce = [
+    "waybar"
+    "[workspace 1 silent] kitty tmux"
+    "[workspace 1 silent] spotify"
+    "[workspace 2 silent] firefox"
+  ];
+
   networking.interfaces.enp130s0.wakeOnLan.enable = true;
   networking.firewall.allowedUDPPorts = [ 9 ];
 
   services.xserver.videoDrivers = ["nvidia"];
+  services.openssh.settings.X11Forwarding = true;
 
   hardware = {
     graphics.enable = true;
@@ -46,14 +59,9 @@
 
   virtualisation.libvirtd.enable = true;
 
-  specialisation = {
-    zen.configuration = {
-      boot.kernelPackages = pkgs.linuxPackages_zen;
-    };
-  };
-  
   services = {
     # Bluetooth fixes
+    # Can be removed when https://github.com/NixOS/nixpkgs/pull/499670 is merged and in 25.11
     udev.extraRules = ''
       SUBSYSTEM=="usb", ENV{ID_VENDOR_ID}=="0489", ENV{ID_MODEL_ID}=="e111", ENV{UDISKS_IGNORE}="1", ENV{ID_MEDIA_PLAYER}="", ENV{ID_MTP_DEVICE}="", ENV{ID_GPHOTO2}="", ENV{ID_INPUT}="", ENV{SOLID_IGNORE}="1", TAG-="uaccess"
 

systems/modules/azure-data-studio.nix

@@ -0,0 +1,7 @@
+{ pkgs, ... }:
+
+{
+  environment.systemPackages = with pkgs; [
+    azuredatastudio
+  ];
+}

systems/modules/common.nix

@@ -8,6 +8,7 @@
   users.defaultUserShell = pkgs.zsh;
 
   environment.systemPackages = with pkgs; [
+    chromium
     gnumake
     git
     jetbrains-toolbox

systems/modules/filezilla.nix

@@ -0,0 +1,7 @@
+{ pkgs, ... }:
+
+{
+  environment.systemPackages = with pkgs; [
+    filezilla
+  ];
+}

systems/modules/gimp.nix

@@ -0,0 +1,7 @@
+{ config, pkgs, ... } :
+
+{
+  environment.systemPackages = with pkgs; [
+    gimp
+  ];
+}

systems/modules/home-manager.nix

@@ -0,0 +1,10 @@
+{ pkgs, ... }:
+
+{
+  home-manager = {
+    useGlobalPkgs = true;
+    useUserPackages = true;
+
+    users.avravels = import home/home.nix;
+  };
+}

systems/modules/home/home.nix

@@ -0,0 +1,32 @@
+{ pkgs, lib, ... }:
+
+{
+  # Home Manager state version
+  home.stateVersion = "25.11";
+
+  home.username = "avravels";
+  home.homeDirectory = "/home/avravels";
+
+  imports = [
+    ./other/fonts.nix
+    ./programs/bitwarden.nix
+    ./programs/kitty.nix
+    ./programs/zsh.nix
+    ./programs/direnv.nix
+    ./programs/firefox.nix
+    ./programs/tmux.nix
+    ./programs/git.nix
+    ./programs/libreoffice.nix
+    ./programs/nvim.nix
+    ./programs/ripgrep.nix
+    ./programs/vscode.nix
+    ./wm/rofi.nix
+    ./wm/cursor.nix
+    ./wm/dconf.nix
+    ./wm/gtk.nix
+    ./wm/waybar.nix
+    ./wm/hyprland.nix
+    ./wm/hyprpaper.nix
+  ];
+
+}

systems/modules/home/other/fonts.nix

@@ -0,0 +1,13 @@
+{ pkgs, ... }:
+
+{
+  fonts.fontconfig.enable = true;
+
+  home.packages = with pkgs; [
+    nerd-fonts.fira-code
+    nerd-fonts.droid-sans-mono
+    nerd-fonts.noto
+    nerd-fonts.hack
+    nerd-fonts.ubuntu
+  ];
+}

systems/modules/home/programs/bitwarden.nix

@@ -0,0 +1,7 @@
+{ pkgs, ...}:
+
+{
+  home.packages = [
+    pkgs.bitwarden-desktop
+  ];
+}

systems/modules/home/programs/direnv.nix

@@ -0,0 +1,13 @@
+{ pkgs, config, ... }:
+
+{
+  programs.direnv = {
+    enable = true;
+    enableZshIntegration = true;
+    nix-direnv.enable = true;
+  };
+  
+  home.file.".config/direnv/direnvrc" = {
+    source = ./direnv/direnvrc;
+  };
+}

systems/modules/home/programs/direnv/direnvrc

@@ -0,0 +1,15 @@
+# Place in ~/.config/direnv/direnvrc
+
+# Two things to know:
+# * `direnv_layour_dir` is called once for every {.direnvrc,.envrc} sourced
+# * The indicator for a different direnv file being sourced is a different $PWD value
+# This means we can hash $PWD to get a fully unique cache path for any given environment
+
+: ${XDG_CACHE_HOME:=$HOME/.cache}
+declare -A direnv_layout_dirs
+direnv_layout_dir() {
+	echo "${direnv_layout_dirs[$PWD]:=$(
+		echo -n "$XDG_CACHE_HOME"/direnv/layouts/
+		echo -n "$PWD" | sha1sum | cut -d ' ' -f 1
+	)}"
+}

systems/modules/home/programs/fastfetch/config.jsonc

@@ -0,0 +1,12 @@
+{
+  "$schema": "https://github.com/fastfetch-cli/fastfetch/raw/master/doc/json_schema.json",
+  "modules": [
+    "os",
+    "uptime",
+    "cpu",
+    "gpu",
+    "memory",
+    "swap",
+    "disk",
+  ]
+}

systems/modules/home/programs/firefox.nix

@@ -0,0 +1,36 @@
+{ pkgs, ... }:
+
+{
+  programs.firefox = {
+    enable = true;
+
+    profiles.default = {
+      settings = {
+        "extensions.activeThemeID" = "firefox-compact-dark@mozilla.org";
+      };
+    };
+
+    policies = {
+      # From https://discourse.nixos.org/t/declare-firefox-extensions-and-settings/36265/17
+      ExtensionSettings = with builtins;
+        let extension = shortId: uuid: {
+          name = uuid;
+          value = {
+            install_url = "https://addons.mozilla.org/en-US/firefox/downloads/latest/${shortId}/latest.xpi";
+            installation_mode = "normal_installed";
+          };
+        };
+        in listToAttrs [
+          (extension "bitwarden-password-manager" "{446900e4-71c2-419f-a6a7-df9c091e268b}")
+          (extension "ublock-origin" "uBlock0@raymondhill.net")
+          (extension "privacy-badger17" "jid1-MnnxcxisBPnSXQ@jetpack")
+          (extension "i-dont-care-about-cookies" "jid1-KKzOGWgsW3Ao4Q@jetpack")
+        ];
+        # To add additional extensions, find it on addons.mozilla.org, find
+        # the short ID in the url (like https://addons.mozilla.org/en-US/firefox/addon/!SHORT_ID!/)
+        # Then, download the XPI by filling it in to the install_url template, unzip it,
+        # run `jq .browser_specific_settings.gecko.id manifest.json` or
+        # `jq .applications.gecko.id manifest.json` to get the UUID
+    };
+  };
+}

systems/modules/home/programs/git.nix

@@ -0,0 +1,27 @@
+{ lib, pkgs, config, ... }:
+
+{
+  options.home.git = {
+    userName = lib.mkOption {
+      type = lib.types.str;
+      default = "Armel van Ravels";
+      description = "Default git user.name for this user";
+    };
+
+    userEmail = lib.mkOption {
+      type = lib.types.str;
+      default = "armel@armel.nl";
+      description = "Default git user.email for this user";
+    };
+  };
+
+  config = {
+    programs.git = {
+      enable = true;
+      settings.user = {
+        name = config.home.git.userName;
+        email = config.home.git.userEmail;
+      };
+    };
+  };
+}

systems/modules/home/programs/kitty.nix

@@ -0,0 +1,8 @@
+{ pkgs, ... }:
+
+{
+  programs.kitty = {
+    enable = true;
+    settings.confirm_quit = false;
+  };
+}

systems/modules/home/programs/libreoffice.nix

@@ -0,0 +1,11 @@
+{ pkgs, ... }:
+
+{
+  home.packages = with pkgs; [
+    libreoffice
+
+    hunspell
+    hunspellDicts.en_US
+    hunspellDicts.nl_NL
+  ];
+}

systems/modules/home/programs/nvim.nix

@@ -0,0 +1,159 @@
+{ pkgs, ... }:
+
+{
+  programs.neovim = {
+    enable = true;
+    defaultEditor = true;
+    extraLuaPackages = ps: [ ps.magick ];
+    extraPackages = [
+      pkgs.ueberzugpp
+      pkgs.imagemagick
+    ];
+
+    plugins = with pkgs.vimPlugins; [
+      neo-tree-nvim
+      catppuccin-nvim
+      tokyonight-nvim
+      nvim-lspconfig
+      nvim-cmp
+      cmp-nvim-lsp
+      cmp-buffer
+      cmp-path
+      plenary-nvim
+      telescope-nvim
+      (nvim-treesitter.withAllGrammars)
+      vim-nix
+      lualine-nvim
+      image-nvim
+    ];
+
+    extraLuaConfig = ''
+      vim.cmd("colorscheme catppuccin-mocha")
+      -- Basic settings
+      vim.o.number = true
+      vim.o.relativenumber = true
+
+      -- =========================
+      -- LSP (Neovim 0.11+ way)
+      -- =========================
+
+      -- Add cmp capabilities
+      local capabilities = require("cmp_nvim_lsp").default_capabilities()
+
+      vim.lsp.config("nil_ls", {
+        capabilities = capabilities,
+      })
+
+      -- PHP LSP
+      vim.lsp.config("intelephense", {
+        capabilities = capabilities,
+      })
+
+      vim.lsp.enable("intelephense")
+
+
+      vim.lsp.enable("nil_ls")
+
+      -- =========================
+      -- nvim-cmp
+      -- =========================
+
+      local cmp = require("cmp")
+
+      cmp.setup({
+        mapping = cmp.mapping.preset.insert({
+          ["<C-Space>"] = cmp.mapping.complete(),
+          ["<CR>"] = cmp.mapping.confirm({ select = true }),
+        }),
+        sources = {
+          { name = "nvim_lsp" },
+          { name = "buffer" },
+          { name = "path" },
+        }
+      })
+
+      -- =========================
+      -- Telescope
+      -- =========================
+
+      local builtin = require("telescope.builtin")
+      vim.keymap.set("n", "<leader>ff", builtin.find_files, {})
+      vim.keymap.set("n", "<leader>fg", builtin.live_grep, {})
+
+      -- =========================
+      -- Lualine (status line with Git branch)
+      -- =========================
+      require('lualine').setup {
+        options = {
+          theme = 'catppuccin',  -- match your colorscheme
+          section_separators = {'', ''},
+          component_separators = {'', ''},
+        },
+        sections = {
+          lualine_a = {'mode'},
+          lualine_b = {'branch'},  -- shows Git branch here
+          lualine_c = {'filename'},
+          lualine_x = {'encoding', 'fileformat', 'filetype'},
+          lualine_y = {'progress'},
+          lualine_z = {'location'}
+        }
+      }
+
+      -- =========================
+      -- image-nvim
+      -- ========================= 
+      require("image").setup({
+        backend = "ueberzug", -- or "ueberzug" or "sixel"
+        processor = "magick_cli", -- or "magick_rock"
+        integrations = {
+        markdown = {
+          enabled = true,
+          clear_in_insert_mode = false,
+          download_remote_images = true,
+          only_render_image_at_cursor = false,
+          only_render_image_at_cursor_mode = "popup", -- or "inline"
+          floating_windows = false, -- if true, images will be rendered in floating markdown windows
+          filetypes = { "markdown", "vimwiki" }, -- markdown extensions (ie. quarto) can go here
+        },
+        asciidoc = {
+          enabled = true,
+          clear_in_insert_mode = false,
+          download_remote_images = true,
+          only_render_image_at_cursor = false,
+          only_render_image_at_cursor_mode = "popup",
+          floating_windows = false,
+          filetypes = { "asciidoc", "adoc" },
+        },
+        neorg = {
+          enabled = true,
+          filetypes = { "norg" },
+        },
+        rst = {
+          enabled = true,
+        },
+        typst = {
+          enabled = true,
+          filetypes = { "typst" },
+        },
+        html = {
+          enabled = false,
+        },
+        css = {
+          enabled = false,
+        },
+      },
+      max_width = nil,
+      max_height = nil,
+      max_width_window_percentage = nil,
+      max_height_window_percentage = 50,
+      scale_factor = 1.0,
+      window_overlap_clear_enabled = false, -- toggles images when windows are overlapped
+      window_overlap_clear_ft_ignore = { "cmp_menu", "cmp_docs", "snacks_notif", "scrollview", "scrollview_sign" },
+      editor_only_render_when_focused = false, -- auto show/hide images when the editor gains/looses focus
+      tmux_show_only_in_active_window = false, -- auto show/hide images in the correct Tmux window (needs visual-activity off)
+      hijack_file_patterns = { "*.png", "*.jpg", "*.jpeg", "*.gif", "*.webp", "*.avif" }, -- render image files as images when opened
+    })
+
+    '';
+  };
+}

systems/modules/home/programs/ripgrep.nix

@@ -0,0 +1,8 @@
+{ pkgs, ... }: 
+
+{
+  home.packages = with pkgs; [
+    ripgrep
+  ];
+}
+

systems/modules/home/programs/tmux.nix

@@ -0,0 +1,5 @@
+{ pkgs, ... }:
+
+{
+  programs.tmux.enable = true;
+}

systems/modules/home/programs/vscode.nix

@@ -0,0 +1,29 @@
+{ pkgs, ... }:
+
+{
+  programs.vscode = {
+    enable = true;
+
+    package = pkgs.vscode.fhs;
+    profiles.default.extensions = with pkgs.vscode-extensions; [
+      ms-dotnettools.csharp
+      ms-dotnettools.csdevkit
+      ms-dotnettools.vscode-dotnet-runtime
+      mkhl.direnv   # Direnv integration for VSCode
+      catppuccin.catppuccin-vsc
+      vscodevim.vim
+    ];
+
+    profiles.default.userSettings = {
+      "editor.lineNumbers" = "relative";
+      "workbench.colorTheme" = "Catppuccin Mocha";
+      "direnv.restart.automatic" = true;
+      "terminal.integrated.defaultProfile.linux" = "zsh";
+      "terminal.integrated.profiles.linux" = {
+        zsh = {
+          path = pkgs.zsh;
+        };
+      };
+    };
+  };
+}

systems/modules/home/programs/zsh.nix

@@ -0,0 +1,19 @@
+{ pkgs, ... }:
+
+{
+  home.file.".zsh/fastfetch.jsonc".source =
+    ./fastfetch/config.jsonc;
+
+  programs.zsh = {
+    enable = true;
+    oh-my-zsh = {
+      enable = true;
+      theme = "agnoster";
+    };
+
+    initContent = ''
+      # Use kitty's ssh helper if running inside kitty
+      [ "$TERM" = "xterm-kitty" ] && alias ssh="kitty +kitten ssh"
+    '';
+  };
+}

systems/modules/home/wm/cursor.nix

@@ -0,0 +1,13 @@
+{ pkgs, ... }:
+
+{
+  home.pointerCursor = {
+#    name = "Bibata-Modern-Ice";   # change to your cursor theme
+#    package = pkgs.bibata-cursors;
+    name = "Adwaita";
+    package = pkgs.adwaita-icon-theme;
+    size = 24;
+    gtk.enable = true;
+    x11.enable = true;
+  };
+}

systems/modules/home/wm/dconf.nix

@@ -0,0 +1,16 @@
+{ pkgs, ... }:
+
+{
+  home.packages = with pkgs; [
+    dconf
+  ];
+
+  dconf = {
+    enable = true;
+    settings = {
+      "org/gnome/desktop/interface" = {
+        color-scheme = "prefer-dark";
+      };
+    };
+  };
+}

systems/modules/home/wm/gtk.nix

@@ -0,0 +1,26 @@
+{ pkgs, ... }:
+
+{
+  gtk = {
+    enable = true;
+    theme = {
+      name = "Orchis-dark";
+      package = pkgs.orchis-theme;
+    };
+    iconTheme = {
+      name = "Adwaita";
+      package = pkgs.adwaita-icon-theme;
+    };
+    cursorTheme = {
+      name = "Adwaita";
+      package = pkgs.adwaita-icon-theme;
+    };
+  };
+
+  home.sessionVariables = {
+    GTK_THEME = "Adwaita:dark"; # GTK apps dark theme
+    MOZ_GTK_THEME = "Adwaita:dark"; # Firefox respects this
+    GDK_DARK_THEME = "1"; # GTK4 apps dark mode
+    CHROME_FORCE_DARK_MODE = "1"; # Chromium / Chrome dark mode
+  };
+}

systems/modules/home/wm/hyprland.nix

@@ -0,0 +1,155 @@
+{ lib, pkgs, config, ... }:
+
+let
+  cfg = config.home.hyprland;
+in
+
+{
+  options.home.hyprland = {
+    execOnce = lib.mkOption {
+      type = lib.types.listOf lib.types.str;
+      default = [ "waybar" ];
+      description = "Commands to run once when Hyprland starts (maps to Hyprland `exec-once`).";
+    };
+  };
+  config = {
+    home.packages = with pkgs; [
+      bzmenu
+      hyprshot
+      hyprlock
+      playerctl
+      speedcrunch
+    ];
+
+    wayland.windowManager.hyprland = {
+      enable = true;
+
+      settings = {
+        ### MONITOR
+        monitor = [
+          ",preferred,auto,1"
+        ];
+
+        ### VARIABLES
+        "$mod" = "SUPER";
+        "$terminal" = "kitty";
+        "$menu" = "rofi -show drun";
+        "$bluetoothMenu" = "bzmenu --launcher rofi";
+        "$files" = "rofi -show filebrowser";
+
+        ### BASIC LAYOUT
+        general = {
+          layout = "dwindle";
+          resize_on_border = true;
+        };
+
+        decoration = {
+          inactive_opacity = 0.8;
+          active_opacity = 0.9;
+          rounding = 5;
+          rounding_power = 2.5;
+          blur = {
+            enabled = true;
+            brightness = 1.0;
+            contrast = 1.0;
+            noise = 0.01;
+
+            vibrancy = 0.2;
+            vibrancy_darkness = 0.5;
+
+            passes = 4;
+            size = 7;
+
+            popups = true;
+            popups_ignorealpha = 0.2;
+          };
+
+          shadow = {
+            enabled = true;
+            color = "rgba(00000055)";
+            ignore_window = true;
+            offset = "0 15";
+            range = 100;
+            render_power = 2;
+            scale = 0.97;
+          };
+        };
+
+        # Use the configurable option here (default `[ "waybar" ]`)
+        exec-once = (if cfg == null then { execOnce = [ "waybar" ]; } else cfg).execOnce;
+
+        ### INPUT
+        input = {
+          kb_layout = "us";
+        };
+
+        ### KEYBINDINGS
+        bind = [
+          # Apps
+          "$mod, RETURN, exec, $terminal"
+          "$mod, D, exec, $menu"
+          "$mod, B, exec, $bluetoothMenu"
+          "$mod, G, exec, $files"
+          "$mod, Q, killactive"
+          "$mod, F, fullscreen"
+          "$mod, M, exit"
+          "$mod, L, exec, hyprlock"
+
+          # show/hide waybar
+          "$mod, W, exec, pkill -SIGUSR1 -f '^waybar$'"
+
+          # Focus
+          "$mod, LEFT,  movefocus, l"
+          "$mod, RIGHT, movefocus, r"
+          "$mod, UP,    movefocus, u"
+          "$mod, DOWN,  movefocus, d"
+
+          # Workspaces
+          "$mod, 1, workspace, 1"
+          "$mod, 2, workspace, 2"
+          "$mod, 3, workspace, 3"
+          "$mod, 4, workspace, 4"
+          "$mod, 5, workspace, 5"
+          "$mod, 6, workspace, 6"
+          "$mod, 7, workspace, 7"
+          "$mod, 8, workspace, 8"
+          "$mod, 9, workspace, 9"
+
+          "$mod SHIFT, 1, movetoworkspace, 1"
+          "$mod SHIFT, 2, movetoworkspace, 2"
+          "$mod SHIFT, 3, movetoworkspace, 3"
+          "$mod SHIFT, 4, movetoworkspace, 4"
+          "$mod SHIFT, 5, movetoworkspace, 5"
+          "$mod SHIFT, 6, movetoworkspace, 6"
+          "$mod SHIFT, 7, movetoworkspace, 7"
+          "$mod SHIFT, 8, movetoworkspace, 8"
+          "$mod SHIFT, 9, movetoworkspace, 9"
+
+          # Window movement
+          "$mod SHIFT, LEFT,  movewindow, l"
+          "$mod SHIFT, RIGHT, movewindow, r"
+          "$mod SHIFT, UP,    movewindow, u"
+          "$mod SHIFT, DOWN,  movewindow, d"
+
+          # Hyprshot
+          "$mod, Z, exec, hyprshot -m region"
+
+          # Media keys
+          ", XF86AudioPlay,        exec, playerctl play-pause"
+          ", XF86AudioMute,        exec, wpctl set-mute @DEFAULT_AUDIO_SINK@ toggle"
+          ", XF86AudioRaiseVolume, exec, wpctl set-volume @DEFAULT_AUDIO_SINK@ 5%+"
+          ", XF86AudioLowerVolume, exec, wpctl set-volume @DEFAULT_AUDIO_SINK@ 5%-"
+          ", XF86AudioNext,        exec, playerctl next"
+          ", XF86AudioPrev,        exec, playerctl previous"
+
+          ", XF86Calculator,       exec, speedcrunch"
+        ];
+
+        bindm = [
+          "$mod, mouse:272, movewindow"
+          "$mod, mouse:273, resizewindow"
+        ];
+      };
+    };
+  };
+}

systems/modules/home/wm/hyprpaper.nix

@@ -0,0 +1,22 @@
+{ config, pkgs, ... }:
+
+let
+  wallpaper = builtins.toString ../backgrounds/monkey.jpg;
+  wallpaper2 = builtins.toString ../backgrounds/bird.jpg;
+in
+{
+  services.hyprpaper = {
+    enable = true;
+
+    settings = {
+      preload = [
+        wallpaper
+        wallpaper2
+      ];
+      wallpaper = [
+        "DP-2,${wallpaper2}"
+        ",${wallpaper}"
+      ];
+    };
+  };
+}

systems/modules/home/wm/rofi.nix

@@ -0,0 +1,13 @@
+{ pkgs, ... }:
+
+{
+  home.packages = [
+    pkgs.rofi-file-browser
+  ];
+
+  programs.rofi = {
+    enable = true;
+    theme = "material";
+    terminal = "${pkgs.kitty}/bin/kitty";
+  };
+}

systems/modules/home/wm/waybar.nix

@@ -0,0 +1,67 @@
+{ pkgs, ... }:
+
+{
+  programs.waybar = {
+    enable = true;
+
+    style = builtins.readFile ./waybar/waybar-style.css;
+
+    settings.mainBar = {
+      layer = "top";
+      position = "top";
+      height = 30;
+
+      modules-left = [
+        "hyprland/workspaces"
+        "mpris"
+      ];
+      
+      modules-center = [
+        "wlr/taskbar"
+      ];
+
+      modules-right = [
+        "pulseaudio"
+        "cpu"
+        "tray"
+        "clock"
+      ];
+
+      pulseaudio = {
+        format = "{icon} {volume}%";
+        format-muted = "󰝟 muted";
+        tooltip = false;
+
+        scroll-step = 5;
+
+        format-icons = {
+          default = [ "󰕿" "󰖀" "󰕾" ];
+        };
+
+        on-click = "wpctl set-mute @DEFAULT_AUDIO_SINK@ toggle";
+      };
+
+      mpris = {
+        player = "spotify";
+        format = "{player_icon} {artist} - {title}";
+        format-paused = "{player_icon} ⏸ {title}";
+        tooltip = true;
+        ignored-players = [ "firefox" "vlc" ];
+      };
+
+      cpu = {
+        format = "  {usage}%";
+        tooltip = false;
+      };
+
+      clock = {
+        tooltip = false;
+      };
+
+      "wlr/taskbar" = {
+        format = "{icon} {name}";
+        on-click = "activate";
+      };
+    };
+  };
+}

systems/modules/home/wm/waybar/waybar-style.css

@@ -0,0 +1,82 @@
+/* ---------------------------
+   Default Waybar Styling
+--------------------------- */
+
+* {
+  color: #ffffff;
+}
+
+
+menu {
+  background-color: #222222;
+  border-radius: 8px;
+  border: 1px solid #313244;
+}
+
+menu menuitem {
+  padding: 6px 12px;
+  color: #cdd6f4;
+}
+
+menu menuitem:hover {
+  background-color: #45475a;
+}
+
+/* General bar */
+#waybar {
+    background-color: #222222;  /* Default dark gray bar */
+    color: #ffffff;             /* Default text color */
+}
+
+/* Modules */
+.module {
+    margin: 0 4px;
+}
+
+/* Hover effect (minimal) */
+.module:hover {
+    opacity: 0.8;
+}
+
+/* Separators */
+.separator {
+    margin: 0 2px;
+}
+
+#taskbar button {
+  background: transparent;
+  border: none;
+  box-shadow: none;
+}
+
+#taskbar button:hover {
+  background-color: rgba(180, 190, 254, 0.15);
+  border-radius: 6px;
+}
+
+#taskbar button.active {
+  background-color: rgba(180, 190, 254, 0.3);
+}
+
+/* Workspace buttons */
+#workspaces button {
+  background: transparent;
+  border: none;
+  box-shadow: none;
+}
+
+/* Hover */
+#workspaces button:hover {
+  background-color: rgba(180, 190, 254, 0.15);
+  border-radius: 6px;
+}
+
+/* Active workspace */
+#workspaces button.active {
+  background-color: rgba(180, 190, 254, 0.35);
+}
+
+/* Icons */
+i {
+    margin-right: 2px;
+}

systems/modules/ollama.nix

@@ -0,0 +1,10 @@
+{ pkgs, ... }:
+
+{
+  services.ollama = {
+    enable = true;
+    package = pkgs.ollama-cuda;
+  };
+
+  services.open-webui.enable = true;
+}

systems/modules/postman.nix

@@ -0,0 +1,7 @@
+{ pkgs, ... }: 
+
+{
+  environment.systemPackages = with pkgs; [
+    postman
+  ];
+}

systems/modules/qbittorrent.nix

@@ -0,0 +1,7 @@
+{ pkgs, ... }: 
+
+{
+  environment.systemPackages = with pkgs; [
+    qbittorrent
+  ];
+}

systems/modules/remmina.nix

@@ -0,0 +1,7 @@
+{ pkgs, ... }: 
+
+{
+  environment.systemPackages = with pkgs; [
+    remmina
+  ];
+}

systems/modules/teams-for-linux.nix

@@ -0,0 +1,7 @@
+{ pkgs, ... }:
+
+{
+  environment.systemPackages = with pkgs; [
+    teams-for-linux
+  ];
+}

systems/modules/users.nix

@@ -7,7 +7,7 @@
     extraGroups = [ "networkmanager" "wheel" "libvirtd" ];
     packages = with pkgs; [
       home-manager
-      discord
+      legcord
       spotify
       protonvpn-gui
     ];

systems/modules/wireguard.nix

@@ -0,0 +1,7 @@
+{ pkgs, ... }:
+
+{
+  environment.systemPackages = with pkgs; [
+    wireguard-tools
+  ];
+}

systems/work/default.nix

@@ -0,0 +1,56 @@
+{ config, pkgs, ... }:
+
+{
+  imports =
+    [
+      ./hardware-configuration.nix
+      ../modules/home-manager.nix
+      ../modules/common.nix
+      ../modules/users.nix
+      ../modules/locales.nix
+      ../modules/services.nix
+      ../modules/programs.nix
+      ../modules/garbage-collection.nix
+      ../modules/printing.nix
+      ../modules/docker.nix
+      ../modules/teams-for-linux.nix
+      ../modules/azure-data-studio.nix
+      ../modules/filezilla.nix
+      ../modules/wireguard.nix
+      ../modules/remmina.nix
+      ../modules/postman.nix
+      ../modules/gimp.nix
+    ];
+
+  boot.loader.systemd-boot.enable = true;
+  boot.loader.efi.canTouchEfiVariables = true;
+
+  boot.plymouth.enable = true;
+  boot.plymouth.theme = "spinner";
+  boot.initrd.systemd.enable = true;
+
+  programs.nix-ld.enable = true;
+
+  networking.hostName = "laptop-armel";
+
+  home-manager.users.avravels.home.hyprland.execOnce = [ "waybar" ];
+
+  home-manager.users.avravels.home.git.userName = "Armel van Ravels";
+  home-manager.users.avravels.home.git.userEmail = "armel@webavance.nl";
+
+  networking.networkmanager.enable = true;
+  networking.nameservers = [ "192.168.68.56" "1.1.1.1" "8.8.8.8" ];
+  networking.firewall.enable = false;
+
+  hardware.graphics.enable = true;
+  services.xserver.videoDrivers = [ "intel" ];
+
+  virtualisation.libvirtd.enable = true;
+
+  networking.hosts = {
+    "127.0.0.1" = [ "local.wormundco.de" "local.wormundco.nl" "local.wormenco.nl" "local.wurmundco.de" ];
+    "149.210.174.226" = [ "kindertelefoon" ];
+  };
+
+  system.stateVersion = "25.11"; # Did you read the comment?
+}

systems/work/hardware-configuration.nix

@@ -0,0 +1,33 @@
+# Do not modify this file!  It was generated by ‘nixos-generate-config’
+# and may be overwritten by future invocations.  Please make changes
+# to /etc/nixos/configuration.nix instead.
+{ config, lib, pkgs, modulesPath, ... }:
+
+{
+  imports =
+    [ (modulesPath + "/installer/scan/not-detected.nix")
+    ];
+
+  boot.initrd.availableKernelModules = [ "xhci_pci" "nvme" "usb_storage" "usbhid" "sd_mod" ];
+  boot.initrd.kernelModules = [ ];
+  boot.kernelModules = [ "kvm-intel" ];
+  boot.extraModulePackages = [ ];
+
+  fileSystems."/" =
+    { device = "/dev/mapper/luks-5217fae8-1b85-4667-abb7-2b4ca7d443ba";
+      fsType = "ext4";
+    };
+
+  boot.initrd.luks.devices."luks-5217fae8-1b85-4667-abb7-2b4ca7d443ba".device = "/dev/disk/by-uuid/5217fae8-1b85-4667-abb7-2b4ca7d443ba";
+
+  fileSystems."/boot" =
+    { device = "/dev/disk/by-uuid/3892-6129";
+      fsType = "vfat";
+      options = [ "fmask=0077" "dmask=0077" ];
+    };
+
+  swapDevices = [ ];
+
+  nixpkgs.hostPlatform = lib.mkDefault "x86_64-linux";
+  hardware.cpu.intel.updateMicrocode = lib.mkDefault config.hardware.enableRedistributableFirmware;
+}